Change filter on multiple pivot tables at once


"Excel VBA Help"

 


Play Friv Now - Play Friv Games
Go Back   The Code Cage Forums > Microsoft Topics > Microsoft Excel Forum
Our Info Pages:-
The Code Cage - Microsoft Office help

Notices

Microsoft Excel Forum Members Post questions in this forum if they are related to using Microsoft Excel, this includes Worksheet Functions, Excel VBA Programming, Simple Macro Code & Charting, Excel formula etc.

New Reply
 
Thread Tools Rate Thread Display Modes
  #1  
Old 29th October 2010, 02:28
mark1920's Avatar
mark1920 mark1920 is offline
Junior Member
MS Office Version: Excel 2007
MS Office Skill Level: Can use VBA
 
Join Date: Oct 2010
Location: Charlotte
Posts: 1
Posts Per Day: 0.00
My Top Tip Count: 0
Thanks to others: 0
Thanked 0 Times in 0 Posts
Reputation: 10 (0) mark1920 is on a distinguished road
Default Change filter on multiple pivot tables at once
     Excel: VBA   


------ Register to get rid of these "In Post" ads! ------

Category: Excel: VBA   

Ok, let me start this by saying that I am new to VBA. I have roughly 20 pivot tables in a workbook, all of which are connected to the same Cube. Is there anyway I can use code so that I can change the filter on one pivot table and change all the other ones at the same time.

The Code Cage Advertisment
Advertisement
  #2  
Old 31st October 2010, 17:01
nsenor udofa's Avatar
nsenor udofa nsenor udofa is offline
Forum VIP
MS Office Version: MS Office 2007
MS Office Skill Level: Proficient in vba
 
Join Date: Oct 2010
Location: Calabar, Nigeria
Posts: 59
Posts Per Day: 0.02
My Top Tip Count: 0
Thanks to others: 3
Thanked 8 Times in 8 Posts
Reputation: 164 (9) nsenor udofa has a spectacular aura aboutnsenor udofa has a spectacular aura about
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


As far as I know, the filters in a pivot table are local to that table. But like you thought, it is possible to filter all the pivot tables in one go. The key is PivotCache. This is the space in memory where the pivot data is stored.

The 1st thing you do, therefore, is to make sure all your pivots look to the same cache for data.
VBA CODE:
Public Sub AttachToOneCache() 
    Dim pvc As Excel.PivotCache 
    Dim pvt As Excel.PivotTable 
    Dim s As Excel.Worksheet 
    Set pvc = ThisWorkbook.PivotCaches(1) 
    For Each s In ThisWorkbook.Worksheets 
        For Each pvt In s.PivotTables 
            If Not pvt.PivotCache Is pvc Then 
                pvt.CacheIndex = pvc.Index 
            End If 
        Next pvt 
    Next s 
End Sub 

You then may add a filter sheet to your workbook and add a list box to the sheet for each item you want to filter. The list boxes should be multiselect with check boxes.
In the attached workbook I have 2 list boxes. You will also need command buttons to
  • Select all the items in each list box
    Deselect all the items in each list box
    Requery the pivot cache

Here are some helper functions you may need
1.
VBA CODE:
Public Sub MakeaList() 
    Dim cn As ADODB.Connection 
    Dim rstList As New ADODB.Recordset 
    Dim aList As Variant 
    With ThisWorkbook.PivotCaches(1) 
        .MakeConnection 
        Set cn = .ADOConnection 
    End With 
    rstList.Open "select distinct a from [sheet1$]", cn 
    aList = rstList.GetRows 
    rstList.Close 
    Set rstList = Nothing 
    aListBox.Column = aList 
End Sub 
This is the routine that fills the 1st List box

2.
VBA CODE:
Public Sub MakebList() 
    Dim varbList As Variant, item As Long 
    Dim in_str As String, strQry As String 
    Dim cn As ADODB.Connection 
    Dim rstList As New ADODB.Recordset 
    Dim aList As Variant 
    With ThisWorkbook.PivotCaches(1) 
        .MakeConnection 
        Set cn = .ADOConnection 
    End With 
    in_str = SelectedItems(aListBox) 
    strQry = "select distinct b from [sheet1$] where a in " & in_str 
    If NoOfItemsSelected(aListBox) > 0 Then 
        rstList.Open strQry, cn 
        varbList = rstList.GetRows 
        rstList.Close 
        Set rstList = Nothing 
        bListBox.Column = varbList 
    Else 
        bListBox.Clear 
    End If 
End Sub 

This fills the 2nd list box (once a selection from the 1st list box is made) with b-values relevant to the 1st list box

3
VBA CODE:
 
Public Property Get aListBox() As MSForms.ListBox 
Set aListBox = Sheet3.ListBox1 
End Property 
 
Public Property Get bListBox() As MSForms.ListBox 
Set bListBox = Sheet3.ListBox2 
End Property 

These are short names for the List Boxes

4.
VBA CODE:
Public Function SelectedItems(lb As MSForms.ListBox) As String 
    Dim item As Long 
    Dim in_str As String 
    in_str = "(" 
    With lb 
        For item = 0 To .ListCount - 1 
            If .Selected(item) Then 
                in_str = in_str & "'" & .List(item) & "'," 
            End If 
        Next item 
    End With 
    in_str = Left(in_str, Len(in_str) - 1) 
    in_str = in_str & ")" 
    SelectedItems = in_str 
End Function 
Constructs the list of selected items in a way the MSJet query will understand.

5.

VBA CODE:
Public Function NoOfItemsSelected(lb As MSForms.ListBox) As Long 
    Dim item As Long 
    With lb 
        For item = 0 To .ListCount - 1 
            If .Selected(item) Then 
                NoOfItemsSelected = NoOfItemsSelected + 1 
            End If 
        Next item 
    End With 
End Function 

The no. of items selected in each list box. If 0, no query is constructed.

6.

VBA CODE:
Public Function QueryWithFilters() As String 
    Dim aFilters As String, bFilters As String, strQry As String 
    If NoOfItemsSelected(aListBox) > 0 Then 
        If NoOfItemsSelected(bListBox) > 0 Then 
            aFilters = SelectedItems(aListBox) 
            bFilters = SelectedItems(bListBox) 
            strQry = "select * from [sheet1$] where a in " & aFilters & " and b in " & bFilters 
            QueryWithFilters = strQry 
        End If 
    End If 
End Function 

The query builder for data refreshment

The rest of the code are event drivers in the filter sheet
VBA CODE:
Option Explicit 
 
Private Sub DeselectAllAButton_Click() 
    Dim item As Long 
    With aListBox 
        For item = 0 To .ListCount - 1 
            .Selected(item) = False 
        Next item 
    End With 
End Sub 
 
Private Sub DeselectAllBButton_Click() 
    Dim item As Long 
    With bListBox 
        If .ListCount > 0 Then 
            For item = 0 To .ListCount - 1 
                .Selected(item) = False 
            Next item 
        End If 
    End With 
End Sub 
 
Private Sub ListBox1_Change() 
    MakebList 
End Sub 
 
Private Sub RefreshPivotsButton_Click() 
    With ThisWorkbook.PivotCaches(1) 
        .CommandType = xlCmdSql 
        .CommandText = QueryWithFilters 
        .Refresh 
    End With 
End Sub 
 
Private Sub SelectAllAButton_Click() 
    Dim item As Long 
    With aListBox 
        For item = 0 To .ListCount - 1 
            .Selected(item) = True 
        Next item 
    End With 
End Sub 
 
Private Sub SelectAllBButton_Click() 
    Dim item As Long 
    With bListBox 
        If .ListCount > 0 Then 
            For item = 0 To .ListCount - 1 
                .Selected(item) = True 
            Next item 
        End If 
    End With 
End Sub 

and the workbook

VBA CODE:
Private Sub Workbook_Open() 
    MakeaList 
End Sub 
Attached Files To view attachments in this forum your post count must be 2 or greater. You currently have 0 posts.

  #3  
Old 1st November 2010, 15:07
Rory's Avatar
Rory Rory is offline
Solution Centre Professional
MS Office Version: 2003 onwards
MS Office Skill Level: Competent technician
 
Join Date: Feb 2010
Location: Ubique
Age: 27
Posts: 871
Posts Per Day: 0.31
My Top Tip Count: 2
Thanks to others: 0
Thanked 112 Times in 109 Posts
Reputation: 1963 (35) Rory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant future
2 Top Tips
Northern_Ireland
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


That assumes you have built your pivot tables using external data (or ADO) in the first place, and you should not use ADO on an open workbook due to memory leaks.
__________________
Rory
Microsoft MVP - Excel

Always listen to advice, even if you don't take it.

The Code Cage Advertisment
Advertisement
  #4  
Old 2nd November 2010, 07:05
nsenor udofa's Avatar
nsenor udofa nsenor udofa is offline
Forum VIP
MS Office Version: MS Office 2007
MS Office Skill Level: Proficient in vba
 
Join Date: Oct 2010
Location: Calabar, Nigeria
Posts: 59
Posts Per Day: 0.02
My Top Tip Count: 0
Thanks to others: 3
Thanked 8 Times in 8 Posts
Reputation: 164 (9) nsenor udofa has a spectacular aura aboutnsenor udofa has a spectacular aura about
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


Quote:
Originally Posted by aflatoon View Post

That assumes you have built your pivot tables using external data (or ADO) in the first place, and you should not use ADO on an open workbook due to memory leaks.

If you check the attached workbooks you will see that the source of data for the pivots is an external data source (source.xls) which is to be preferred for the separation of data layer from the presentation layer.

You have memory leaks in using ADO in excel if you are connecting to an open workbook. The source workbook does not need to be opened to manipulate the pivot tables. In fact, Microsoft's default method for connecting pivot tables to external data sources including excel files is via ADO. ADO is therefore not likely to lead to memory leaks in this instance.

The use of ADO against open workbooks is ill advised but there are ways to go around it. This is the Microsoft recommendation. I have used it with great success in many of my projects.

ADO is something Excel and other VBA developers should be encouraged to embrace and not scared away from. It can make your work very neat and robust. If you have a different data source, all you have to do is change the connection string, for instance.

Of course, your alternative input is welcome.


Last edited by nsenor udofa; 2nd November 2010 at 07:19.
  #5  
Old 2nd November 2010, 10:54
Rory's Avatar
Rory Rory is offline
Solution Centre Professional
MS Office Version: 2003 onwards
MS Office Skill Level: Competent technician
 
Join Date: Feb 2010
Location: Ubique
Age: 27
Posts: 871
Posts Per Day: 0.31
My Top Tip Count: 2
Thanks to others: 0
Thanked 112 Times in 109 Posts
Reputation: 1963 (35) Rory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant future
2 Top Tips
Northern_Ireland
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


Whether you keep your data in a separate workbook depends entirely on what you do with it. If you only use pivots or queries to access it, then sure it makes sense to keep it in a separate workbook. If you want to use formulas too, then I think it's better to keep it in the same workbook.
As regards ADO, I specifically said the memory leak applied to open workbooks; I was warning people against using it to build pivots off data in the same workbook. And I certainly did not suggest that people should avoid ADO, or be scared by it.
Purely as an alternative to requerying the datasource repeatedly, you could apply filters to all the tables - with 2007 and later it's a lot simpler than with early versions where you had to iterate all the items for anything other than a page field.
__________________
Rory
Microsoft MVP - Excel

Always listen to advice, even if you don't take it.

  #6  
Old 2nd November 2010, 21:44
nsenor udofa's Avatar
nsenor udofa nsenor udofa is offline
Forum VIP
MS Office Version: MS Office 2007
MS Office Skill Level: Proficient in vba
 
Join Date: Oct 2010
Location: Calabar, Nigeria
Posts: 59
Posts Per Day: 0.02
My Top Tip Count: 0
Thanks to others: 3
Thanked 8 Times in 8 Posts
Reputation: 164 (9) nsenor udofa has a spectacular aura aboutnsenor udofa has a spectacular aura about
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


Mark1920 says he has 20 pivot tables in a workbook using the same data source. I can only imagine the cumbersomeness of going through each table and applying the same filter.

May be it is for this reason he asked for help with VBA.

The Code Cage Advertisment
Advertisement
  #7  
Old 2nd November 2010, 22:21
Rory's Avatar
Rory Rory is offline
Solution Centre Professional
MS Office Version: 2003 onwards
MS Office Skill Level: Competent technician
 
Join Date: Feb 2010
Location: Ubique
Age: 27
Posts: 871
Posts Per Day: 0.31
My Top Tip Count: 2
Thanks to others: 0
Thanked 112 Times in 109 Posts
Reputation: 1963 (35) Rory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant future
2 Top Tips
Northern_Ireland
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


I guess I wasn't clear that I meant doing that with VBA, not by hand!
__________________
Rory
Microsoft MVP - Excel

Always listen to advice, even if you don't take it.

  #8  
Old 3rd November 2010, 07:11
nsenor udofa's Avatar
nsenor udofa nsenor udofa is offline
Forum VIP
MS Office Version: MS Office 2007
MS Office Skill Level: Proficient in vba
 
Join Date: Oct 2010
Location: Calabar, Nigeria
Posts: 59
Posts Per Day: 0.02
My Top Tip Count: 0
Thanks to others: 3
Thanked 8 Times in 8 Posts
Reputation: 164 (9) nsenor udofa has a spectacular aura aboutnsenor udofa has a spectacular aura about
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


OK, if you have time lets see the code and test it for speed with the ADO solution.

  #9  
Old 3rd November 2010, 15:00
Rory's Avatar
Rory Rory is offline
Solution Centre Professional
MS Office Version: 2003 onwards
MS Office Skill Level: Competent technician
 
Join Date: Feb 2010
Location: Ubique
Age: 27
Posts: 871
Posts Per Day: 0.31
My Top Tip Count: 2
Thanks to others: 0
Thanked 112 Times in 109 Posts
Reputation: 1963 (35) Rory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant futureRory has a brilliant future
2 Top Tips
Northern_Ireland
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


A bit rough and ready, but for synching all the page fields on pivot tables in the workbook (no matter which one you alter), something like this:
VBA CODE:
 
Private Sub Workbook_SheetPivotTableUpdate(ByVal Sh As Object, ByVal Target As PivotTable) 
    On Error Resume Next 
    Dim ws As Worksheet 
    Dim wsMain As Worksheet 
    Dim ptMaster As PivotTable 
    Dim pt As PivotTable 
     
    On Error Resume Next 
    Set wsMain = Sh 
    Set ptMaster = Target 
     
    Application.EnableEvents = False 
     
    For Each ws In ThisWorkbook.Worksheets 
        If ws.Name <> wsMain.Name Then 
            For Each pt In ws.PivotTables 
                SynchPageFields ptMaster, pt 
            Next pt 
             
        Else 
            For Each pt In Sh.PivotTables 
                If pt.TableRange1.address <> ptMaster.TableRange1.address Then _ 
                SynchPageFields ptMaster, pt 
            Next pt 
             
        End If 'ws.Name <> wsMain.Name
         
    Next ws 
     
    Application.EnableEvents = True 
     
End Sub 
Private Sub SynchPageFields(ptMain As PivotTable, ptSub As PivotTable) 
    Dim pfMain As PivotField 
    Dim pi As PivotItem 
    Dim pf As PivotField 
     
    ptSub.RefreshTable 
    For Each pfMain In ptMain.PageFields 
        For Each pf In ptSub.PageFields 
            If pf.Name = pfMain.Name Then 
                For Each pi In pf.PivotItems 
                    If pi.Name = pfMain.CurrentPage Then 
                        pf.CurrentPage = pi.Name 
                        Exit For 
                    End If 
                Next pi 
            End If 
        Next pf 
    Next pfMain 
End Sub 
__________________
Rory
Microsoft MVP - Excel

Always listen to advice, even if you don't take it.

The Code Cage Advertisment
Advertisement

To stop seeing these ads and get other benefits check This page!

  #10  
Old 4th November 2010, 12:45
DonkeyOte's Avatar
DonkeyOte DonkeyOte is offline
Junior Member
MS Office Version: MS Office 2002,2007,2010
MS Office Skill Level: Proficient with MS Office
 
Join Date: Apr 2009
Location: Suffolk, UK
Posts: 36
Posts Per Day: 0.01
My Top Tip Count: 0
Thanks to others: 0
Thanked 8 Times in 7 Posts
Reputation: 160 (10) DonkeyOte has a spectacular aura aboutDonkeyOte has a spectacular aura about
Default Re: Change filter on multiple pivot tables at once

------ Register to get rid of these "In Post" ads! ------


I've not reviewed the code in any depth but you should certainly be toggling ManualUpdate on the Pivot as part of your procedure.

Probably also worth considering multi page field selection - and on that note it's worth mentioning that code for XL2007+ when compared to earlier versions would be very different.

edit: figured I should at least add some code to that end... the below does not relate to this question specifically but is added to illustrate multi page field selection etc...

VBA CODE:
Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable) 
    Dim ptTable As PivotTable, ptField As PivotField, ptItem As PivotItem 
    Dim vFields As Variant, lngField As Long, boolMulti As Boolean 
    On Error Goto ExitPoint 
    Application.ScreenUpdating = False 
    Application.EnableEvents = False 
    vFields = Array("Customer", "Month_Trial_Began", "Payment_Interval", "Media", "Guide") 
    For lngField = LBound(vFields) To UBound(vFields) Step 1 
        For Each ptTable In ActiveSheet.PivotTables 
            If ptTable <> Target Then 
                ptTable.ManualUpdate = True 
                Set ptField = ptTable.PivotFields(vFields(lngField)) 
                Select Case ptField.Orientation 
                Case xlRowField 
                    For Each ptItem In ptField.PivotItems 
                        ptItem.Visible = Target.PivotFields(vFields(lngField)).PivotItems(ptItem.Value).Visible 
                    Next ptItem 
                Case xlPageField 
                    boolMulti = Target.PivotFields(vFields(lngField)).EnableMultiplePageItems 
                    With ptField 
                        .ClearAllFilters 
                        Select Case boolMulti 
                        Case False 
                            .CurrentPage = Target.PivotFields(vFields(lngField)).CurrentPage.Value 
                        Case True 
                            .CurrentPage = "(All)" 
                            For Each ptItem In Target.PivotFields(vFields(lngField)).PivotItems 
                                .PivotItems(ptItem.Name).Visible = ptItem.Visible 
                            Next ptItem 
                            .EnableMultiplePageItems = boolMulti 
                        End Select 
                    End With 
                    boolMulti = False 
                End Select 
                Set ptField = Nothing 
                ptTable.ManualUpdate = False 
            End If 
        Next ptTable 
    Next lngField 
ExitPoint: 
    Application.EnableEvents = True 
    Application.ScreenUpdating = True 
End Sub 


Last edited by DonkeyOte; 4th November 2010 at 12:50.
The Code Cage Advertisment
Advertisement
New Reply
The Code Cage at Facebookhe Code Cage at Twitter


Tags
ado, change, filter, multiple, pivot, query, tables

Thread Tools
Display Modes Rate This Thread
Rate This Thread:

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

The Code Cage Affilliates



http://www.thecodecage.com/forumz tested by McAfee Security http://www.thecodecage.com/forumz tested by McAfee Security

All times are GMT +1. The time now is 15:52.


Powered by vBulletin® Version 3.8.7
Copyright ©2000 - 2017, vBulletin Solutions, Inc.
Template-Modifications by TMS
No part of this board, functionality or creatives may be copied or reproduced either in part or full without the express permission of The Code Cage Team.
Copyright ©2008 - , Simon lloyd.
We are not associated with nor employed by Microsoft in any way, we simply provide resources!
All MS office icons are registered trademarks of the application they represent and are used with permission from Microsoft
UA-8135493-1
Cultural Forum | Study at Malaysian University
X vBulletin 3.8.7 Debug Information
  • Page Generation 0.36641 seconds
  • Memory Usage 6,818KB
  • Queries Executed 16 (?)
More Information
Template Usage:
  • (1)SHOWTHREAD
  • (1)ad_footerEnd
  • (1)ad_footerStart
  • (1)ad_footer_end
  • (1)ad_footer_start
  • (1)ad_headerEnd
  • (1)ad_header_end
  • (1)ad_header_logo
  • (1)ad_leftcolumn_code
  • (1)ad_navbar_below
  • (5)ad_postbit_below
  • (1)ad_showthread_beforeqr
  • (1)ad_showthread_firstpost
  • (1)ad_showthread_firstpost_sig
  • (1)ad_showthread_firstpost_start
  • (11)bbcode_code
  • (1)bbcode_quote
  • (1)footer
  • (1)forumjump
  • (1)forumrules
  • (1)gobutton
  • (1)header
  • (1)headinclude
  • (10)helpful_answers
  • (1)helpfulanswers_javascript
  • (1)navbar
  • (3)navbar_link
  • (2)navbar_noticebit
  • (41)option
  • (1)pagenav
  • (1)pagenav_curpage
  • (2)pagenav_pagelink
  • (10)post_thanks_box
  • (1)post_thanks_javascript
  • (1)post_thanks_navbar_search
  • (10)post_thanks_postbit_info
  • (10)postbit
  • (1)postbit_attachment
  • (10)postbit_ctoptip
  • (10)postbit_onlinestatus
  • (55)postbit_reputation
  • (10)postbit_wrapper
  • (1)showthread_changepostsowner_link
  • (1)showthread_extra_fields
  • (1)showthread_quickreply_mrgdp
  • (1)showthread_reason_popup
  • (1)spacer_close
  • (1)spacer_open
  • (1)su_form
  • (7)tagbit
  • (1)tagbit_wrapper 

Phrase Groups Available:
  • global
  • inlinemod
  • postbit
  • posting
  • reputationlevel
  • showthread
Included Files:
  • ./showthread.php
  • ./global.php
  • ./includes/init.php
  • ./includes/class_core.php
  • ./includes/config.php
  • ./includes/functions.php
  • ./includes/class_datastore.php
  • ./includes/class_hook.php
  • ./awcoding/plugins/awc.php
  • ./awcoding/plugins/ds.php
  • ./awcoding/plugins/ss.php
  • ./includes/functions_notice.php
  • ./mobiquo/smartbanner.php
  • ./mobiquo/include/classTTConnection.php
  • ./mobiquo/smartbanner/head.inc.php
  • ./includes/functions_bigthree.php
  • ./includes/class_postbit.php
  • ./includes/class_bbcode.php
  • ./includes/vbatags.php
  • ./includes/functions_reputation.php
  • ./includes/functions_post_thanks.php
  • ./includes/functions_misc.php 

Hooks Called:
  • init_startup
  • cache_permissions
  • fetch_threadinfo_query
  • fetch_threadinfo
  • fetch_foruminfo
  • style_fetch
  • cache_templates
  • global_start
  • parse_templates
  • fetch_musername
  • notices_check_start
  • notices_check_criteria
  • notices_noticebit
  • global_setup_complete
  • showthread_start
  • showthread_getinfo
  • forumjump
  • showthread_post_start
  • showthread_query_postids
  • showthread_query
  • helpfulanswers_showthreadorpost
  • bbcode_fetch_tags
  • bbcode_create
  • showthread_postbit_create
  • postbit_factory
  • postbit_display_start
  • post_thanks_function_post_thanks_off_start
  • post_thanks_function_post_thanks_off_end
  • post_thanks_function_fetch_thanks_start
  • post_thanks_function_fetch_thanks_end
  • post_thanks_function_thanked_already_start
  • post_thanks_function_thanked_already_end
  • helpfulanswers_show_normal
  • reputation_power
  • reputation_image
  • postbit_imicons
  • bbcode_parse_start
  • bbcode_parse_complete_precache
  • bbcode_parse_complete
  • postbit_display_complete
  • error_fetch
  • postbit_attachment
  • pagenav_page
  • pagenav_complete
  • tag_fetchbit
  • tag_fetchbit_complete
  • forumrules
  • navbits
  • navbits_complete
  • showthread_complete